# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Florian Pritz <flo@xinu.at>
# Contributor: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
# Contributor: Dan McGee <dan@archlinux.org>
# Contributor: Jaroslaw Rosiek <philosoph@interia.pl>
# Contributor: Darwin Bautista <djclue917@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=asciidoc
pkgver=9.1.1
pkgrel=2
pkgdesc='Text document format for short documents, articles, books and UNIX man pages'
arch=('any')
url='https://asciidoc.org/'
license=('GPL')
depends=('python' 'libxslt' 'docbook-xsl')
checkdepends=('dblatex' 'graphviz' 'lilypond' 'source-highlight')
optdepends=('graphviz: graphviz-filter'
            'lilypond: music-filter'
            'imagemagick: music-filter'
            'source-highlight: source-highlight-filter'
            'dblatex: pdf generation'
            'fop: alternative pdf generation'
            'w3m: text generation'
            'lynx: alternative text generation')
source=("https://github.com/asciidoc-py/asciidoc-py/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('914dfc1542c30bd47faa0aaaae0985cb57d0ca584015729ccd1b94d90da3a616')
b2sums=('6968f95f03684f54c241cf2db8b8b1e264cc53f400feeb618b20325001b52d5086c7f105e583d6bae41b1e0370ebd9a6a3021b956b0d0d63f1765436cccd39a2')

prepare() {
  cd ${pkgname}-py-${pkgver}

  autoconf
}

build() {
  cd ${pkgname}-py-${pkgver}

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make manpages
}

check() {
  cd ${pkgname}-py-${pkgver}

  make test
}

package() {
  cd ${pkgname}-py-${pkgver}

  make install DESTDIR="${pkgdir}"
  make docs DESTDIR="${pkgdir}"

  install -Dm644 asciidocapi.py \
    "${pkgdir}/$(python -c 'import sysconfig; print(sysconfig.get_paths()["platlib"])')"/asciidocapi.py
}
