# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>

pkgname=authoscope
pkgver=0.8.0
pkgrel=1
pkgdesc='Scriptable network authentication cracker'
url='https://github.com/kpcyrd/authoscope'
depends=('openssl' 'lua52' 'libcap' 'zlib')
makedepends=('cargo')
arch=('x86_64')
license=('GPL3')
install=authoscope.install
provides=('badtouch')
conflicts=('badtouch')
replaces=('badtouch')
source=(https://github.com/kpcyrd/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://github.com/kpcyrd/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc)
sha512sums=('3a737999e6e021dfe71ded8fc07985e71ba0a685dc0a5981f34bc8e7cd6d22be029ced2d73e78ebf6630f473691d4dea859ba0fa67183fe8d8f64cf7f858a083'
            'SKIP')
b2sums=('86fa7a8f41bb34083f56b901fd38adab52f035840aeb2f7e225d8acf6521512886140adc817e03eadbdd74b1db5f2287a98ece4e7cfb168c04a8d9357e8b49a9'
        'SKIP')
validpgpkeys=('64B13F7117D6E07D661BBCE0FE763A64F5E54FD6')

build() {
  cd ${pkgname}-${pkgver}
  cargo build --release --locked
}

check() {
  cd ${pkgname}-${pkgver}
  cargo test --release --locked
}

package() {
  cd ${pkgname}-${pkgver}
  install -Dm 755 target/release/${pkgname} \
    target/release/badtouch \
    -t "${pkgdir}/usr/bin"

  install -d "${pkgdir}/usr/share/bash-completion/completions" \
             "${pkgdir}/usr/share/zsh/site-functions" \
             "${pkgdir}/usr/share/fish/vendor_completions.d"
  "${pkgdir}/usr/bin/authoscope" completions bash > "${pkgdir}/usr/share/bash-completion/completions/authoscope"
  "${pkgdir}/usr/bin/authoscope" completions zsh > "${pkgdir}/usr/share/zsh/site-functions/_authoscope"
  "${pkgdir}/usr/bin/authoscope" completions fish > "${pkgdir}/usr/share/fish/vendor_completions.d/authoscope.fish"

  install -Dm 644 docs/authoscope.1 -t "${pkgdir}/usr/share/man/man1"
  install -Dm 644 scripts/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et:
