# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ainola
# Contributor: rtfreedman

_name=CsoundQt
pkgname=csoundqt
pkgver=0.9.8.1
pkgrel=1
epoch=1
pkgdesc="A frontend for Csound"
arch=('x86_64')
url="https://csoundqt.github.io/"
license=('CCPL' 'FDL' 'GPL' 'LGPL2.1')
groups=('pro-audio')
depends=('csound-doc' 'gcc-libs' 'glibc' 'hicolor-icon-theme'  'qt5-base'
'qt5-declarative' 'qt5-webengine')
makedepends=('csound' 'rtmidi')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('e27590f7cc5802dce55f6b3f0f1b477a68a164c65636967d5a87c71d73b389c31db755c4029496c9ab61f40b1c03333afd34c56fa2026a4cae9a3de001d26023')

prepare() {
  mv -v "${_name}-${pkgver}" "${pkgname}-${pkgver}"
}

build() {
  cd "${pkgname}-${pkgver}"
  qmake-qt5 qcs.pro \
    SHARE_DIR="${pkgdir}/usr/share" \
    INSTALL_DIR="${pkgdir}/usr" \
    CONFIG+=rtmidi \
    CONFIG+=html_webengine \
    CONFIG+=record_support
  make
}

package() {
  depends+=('libcsnd6.so' 'libcsound64.so' 'librtmidi.so')
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  # docs
  install -vDm 644 {ChangeLog,README.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}/"
}
