# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=deepin-font-manager
pkgver=5.8.0.24
pkgrel=1
pkgdesc='A font management tool for Deepin desktop'
arch=('x86_64')
url="https://github.com/linuxdeepin/deepin-font-manager"
license=('GPL3')
depends=('deepin-qt5integration')
makedepends=('cmake' 'deepin-file-manager' 'gmock' 'gtest' 'ninja' 'qt5-tools')
optdepends=('deepin-file-manager: font preview in file manager')
groups=('deepin-extra')
source=("https://github.com/linuxdeepin/deepin-font-manager/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('3da48cd3ff3de91893286714deff9ae44442407bbc14c7ecccb60ca1d52c73133f6b29644d70c42a7baa317bec3092e9061ebeb84b252ce2e4c34dd5b0052396')

prepare() {
  cd deepin-font-manager-$pkgver

  # Fix linker flags
  sed -i 's/CMAKE_EXE_LINKER_FLAGS "-pie"/CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pie"/' deepin-font-manager/CMakeLists.txt

  # Fix file manager plugin install dir
  sed -i 's|lib/x86_64-linux-gnu/|lib/|' deepin-font-preview-plugin/CMakeLists.txt
}

build() {
  cd deepin-font-manager-$pkgver
  cmake -GNinja . -DPLUGIN_INSTALL_DIR=
  ninja
}

check() {
  cd deepin-font-manager-$pkgver
  ninja test || :
}

package() {
  cd deepin-font-manager-$pkgver
  DESTDIR="$pkgdir" ninja install
}
