# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=deepin-network-utils
pkgver=5.4.12
pkgrel=1
pkgdesc='DDE network utils'
arch=('x86_64')
url="https://github.com/linuxdeepin/dde-network-utils"
license=('GPL3')
depends=('deepin-qt-dbus-factory' 'gio-qt' 'gsettings-qt')
makedepends=('qt5-tools' 'gtest')
groups=('deepin')
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxdeepin/dde-network-utils/archive/$pkgver.tar.gz")
sha512sums=('408842d21a443903d945067c7db9746ee3355cfef67a3ec1d928059670d0ad9cbeb93f9008f5eb47f8b8edd6b1d418a4477363f6032f0f1643579eddb56ff527')

prepare() {
  cd dde-network-utils-$pkgver
  # Use our own url instead of commercial company's homepage
  sed -i '/www.uniontech.com/i \    "https://archlinux.org/favicon.ico",' dde-network-utils/connectivitychecker.cpp
}

build() {
  cd dde-network-utils-$pkgver
  qmake-qt5 PREFIX=/usr
  make
}

check() {
  cd dde-network-utils-$pkgver
  # make test
}

package() {
  cd dde-network-utils-$pkgver
  make INSTALL_ROOT="$pkgdir" install
}
