# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: csslayer <wengxt AT gmail com>

pkgname=fcitx
pkgdesc="Flexible Context-aware Input Tool with eXtension"
pkgver=4.2.9.8
pkgrel=1
groups=('fcitx-im')
arch=('x86_64')
url="https://fcitx-im.org"
license=('GPL' 'LGPL')
provides=('fcitx-gtk2' 'fcitx-gtk3')
conflicts=('fcitx-gtk2' 'fcitx-gtk3')
replaces=('fcitx-gtk2' 'fcitx-gtk3')
depends=('pango' 'libxinerama' 'gtk-update-icon-cache' 'shared-mime-info'
          'hicolor-icon-theme' 'desktop-file-utils' 'libxkbfile'
          'libxfixes' 'dbus' 'icu' 'libxkbcommon')
optdepends=('enchant: for word predication support'
            'opencc: optional engine to do chinese convert'
            'gettext: for fcitx-po-parser'
            'fcitx-configtool: for configuration (GTK based)'
            'kcm-fcitx: for configuration under KDE')
makedepends=('extra-cmake-modules' 'doxygen' 'gtk2' 'gtk3' 'mesa' 'opencc'
             'iso-codes' 'gobject-introspection' 'enchant' 'python')
source=("https://download.fcitx-im.org/$pkgname/$pkgname-${pkgver}_dict.tar.xz"{,.sig})
sha512sums=('50a954c3178f53fd2d441cdaf81fb44a7fe8dfb263fa6d8dd4ee4884fc7ae8321880c726c9366d11e2a4ac8da2233268d06e5d0800d4527ba0bdb1a1430248ed'
            'SKIP')
validpgpkeys=('2CC8A0609AD2A479C65B6D5C8E8B898CBF2412F9')  # Weng Xuetian

prepare() {
  mkdir build

  sed -e 's|enchant/enchant.h|enchant-2/enchant.h|' -i $pkgname-$pkgver/cmake/FindEnchant.cmake
}

build() {
  cd build

  cmake ../$pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DSYSCONFDIR=/etc \
    -DFORCE_OPENCC=ON \
    -DFORCE_PRESAGE=ON \
    -DFORCE_ENCHANT=ON \
    -DENABLE_TEST=ON \
    -DENABLE_QT=OFF \
    -DENABLE_GTK2_IM_MODULE=ON \
    -DENABLE_GTK3_IM_MODULE=ON \
    -DENCHANT_INCLUDE_DIR=/usr/include/enchant-2/ \
    -DENCHANT_LIBRARIES=/usr/lib/libenchant-2.so
  make
}

check() {
  cd build
  make test
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
