# Maintainer: Sergej Pupykin <arch+pub@sergej.pp.ru>
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: ajs124 < aur AT ajs124 DOT de >

pkgname=firejail
pkgver=0.9.66
pkgrel=3
pkgdesc='Linux namespaces sandbox program'
arch=('x86_64')
url=https://github.com/netblue30/firejail
license=('GPL2')
depends=('apparmor')
optdepends=('xdg-dbus-proxy: for D-Bus filtering')
backup=('etc/apparmor.d/local/firejail-default'
        'etc/firejail/firejail.config'
        'etc/firejail/login.users')
install=firejail.install
source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.xz"{,.asc})
sha256sums=('8a849ea2f3922901033a407b9498d48915260e7c3381f6cf151c51a73c952d0f'
            'SKIP')
b2sums=('43243e4d2773f007c9a7ce4e63b009b63113055baaffa5125d279124967f5c07d510edf431b568bbf5d6cf04501f5645accb5756af80298750d8f0ef35f9a88b'
        'SKIP')
validpgpkeys=('F951164995F5C4006A73411E2CCB36ADFC5849A7')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --enable-apparmor
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}
