# Maintainer: Bruno Pagani <archange@archlinux.org>

pkgbase=gmt
pkgname=(gmt gmt-doc)
pkgver=6.2.0
pkgrel=1
pkgdesc="Generic Mapping Tools for manipulating and plotting geographic and cartesian data"
arch=(x86_64)
url="https://www.generic-mapping-tools.org"
license=(LGPL)
makedepends=(cmake blas curl fftw gdal geos lapack openmp netcdf pcre zlib)
source=(https://github.com/GenericMappingTools/gmt/releases/download/${pkgver}/${pkgname}-${pkgver}-src.tar.xz)
sha256sums=(a01f0a14d48bbc0b14855670f366df3cb8238f0ccdfa26fe744968b4f1c14d54)

build() {
  cmake -B build -S ${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DGMT_LIBDIR=lib \
    -DGMT_DATADIR=share/gmt \
    -DGMT_MANDIR=share/man \
    -DGMT_DOCDIR=share/doc/gmt \
    -DGMT_ENABLE_OPENMP=ON \
    -DGSHHG_ROOT=/usr/share/gmt/coast \
    -DDCW_ROOT=/usr/share/gmt/dcw \
    -DCOPY_GSHHG=OFF \
    -DCOPY_DCW=OFF
  make -C build
}

package_gmt() {
  depends=(blas curl fftw gdal geos lapack openmp netcdf pcre zlib)
  optdepends=(
    'gmt-doc: documentation'
    'ghostscript'
    'python-sphinx'
  )
#    'gmt-coast: coastlines'
#    'gmt-dcw: digital chart of the world polygon map'

  make -C build DESTDIR="${pkgdir}" install
  mv "${pkgdir}"/usr/share/doc "${srcdir}"/
}

package_gmt-doc() {
  install -d "${pkgdir}"/usr/share/
  mv doc "${pkgdir}"/usr/share/
}
