# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Tom Richards <tom@tomrichards.net>

pkgname=gnome-games
pkgver=40.0
pkgrel=2
pkgdesc='Simple game launcher for GNOME'
arch=('x86_64')
url='https://wiki.gnome.org/Apps/Games'
license=('GPL3')
groups=('gnome-extra')
depends=('grilo' 'libarchive' 'libhandy' 'libmanette' 'retro-gtk' 'tracker3')
makedepends=('appstream-glib' 'meson' 'vala')
optdepends=('libretro-blastem: Support for Sega Genesis (Mega Drive) games'
            'libretro-citra: Support for Nintendo 3DS games'
            'libretro-flycast: Support for Dreamcast games'
            'libretro-gambatte: Support for Game Boy and Game Boy Color games'
            'libretro-mgba: Support for Game Boy Advance games'
            'libretro-nestopia: Support for Nintendo Entertainment System and Famicom Disk System games'
            'libretro-parallel-n64: Support for Nintendo 64 games'
            'libretro-picodrive: Support for Sega Master System, Sega 32X, Sega CD (Mega-CD), Sega Genesis (Mega Drive) and Sega Pico games')
source=("https://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz"
        'tracker3.patch')
sha256sums=('32cd413f89292a74b0a84a5a30d0f4878ce42caea36374b1fb4dce3b4f6adf0f'
            '6eaa476f7de1b17848ea64ce99b583a431c3cce6b48d49f034ac2d611a1bdb27')

prepare() {
  cd $pkgname-$pkgver
  # Port to Tracker 3
  patch -Np1 -i ../tracker3.patch
}

build() {
  arch-meson $pkgname-$pkgver build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build

  # Install *.libretro files
  install -dm755 "$pkgdir/usr/lib/libretro/"
  install -Dm644 $pkgname-$pkgver/flatpak/libretro-cores/*.libretro "$pkgdir/usr/lib/libretro/"
}
