# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=gwenhywfar
pkgver=5.6.0
pkgrel=1
pkgdesc="OS abstraction functions for various projects"
arch=('x86_64')
url="https://www.aquamaniac.de/"
license=('LGPL')
depends=('gnutls' 'libgcrypt' 'openssl')
makedepends=('git' 'gtk3' 'qt5-base')
optdepends=('gtk3: for the GTK3 UI'
            'qt5-base: for the Qt5 UI')
source=(https://www.aquamaniac.de/rdm/attachments/download/364/$pkgname-$pkgver.tar.gz
        https://www.aquamaniac.de/rdm/attachments/download/363/$pkgname-$pkgver.tar.gz.asc)
sha256sums=('57af46920991290372752164f9a7518b222f99bca2ef39c77deab57d14914bc7'
            'SKIP')
validpgpkeys=(42400AF5EB2A17F0A69BB551E9899D784A977416) # AqBanking Package Key <packages@aqbanking.de>

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --enable-system-certs --with-guis="gtk3 qt5"
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}
