# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=ral
pkgname=haskell-ral
pkgver=0.2
pkgrel=36
pkgdesc="Random access lists"
url="https://github.com/phadej/vec"
license=("GPL")
arch=('x86_64')
depends=('ghc-libs' 'haskell-quickcheck' 'haskell-adjunctions' 'haskell-bin' 'haskell-distributive'
         'haskell-fin' 'haskell-hashable' 'haskell-indexed-traversable' 'haskell-semigroupoids')
makedepends=('ghc' 'uusi')
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha512sums=('21174789d765120ec08cfd0cd0ec0552fd4564cd9a799355a219d290072b517cbb916d5f0a7aefa918815c943dd472cec34ba3508fe5e20236fafa044965b85f')

prepare() {
  cd $_hkgname-$pkgver
  gen-setup
}

build() {
  cd $_hkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'

  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
  cd $_hkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
