# Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor: FigoDaPaura <ffigoDaPaura>

pkgname=lib32-virtualgl
pkgver=2.6.5
pkgrel=1
pkgdesc="32-bit serverside components for 64-bit VirtualGL servers"
arch=('x86_64')
url="https://virtualgl.org"
license=('LGPL')
depends=('virtualgl' 'lib32-libxv' 'lib32-glu' 'lib32-libjpeg-turbo' 'lib32-opencl-driver' 'lib32-ocl-icd')
makedepends=('lib32-libxv' 'lib32-glu' 'virtualgl' 'cmake' 'gcc-multilib' 'lib32-mesa' 'lib32-mesa-libgl' 'lib32-libxtst' 'opencl-headers')
source=("https://downloads.sourceforge.net/project/virtualgl/${pkgver}/VirtualGL-${pkgver}.tar.gz"{,.sig})
sha512sums=('0ab9e744e400d323bc16f6e2cf310905361745ea4da9e9e9a41cbeb45b1d661eebd38a0fad8ae5df4664d02b341de44c5730af8437e6ef49c7351b4afb953532'
            'SKIP')
b2sums=('4dc38a144e197ea7578dd29eea5eb69fb3e96a75c2729605f6678fbc96f3cf039c2e1780aa69ca8836771f72731cd8cdd795237d69d4b591e330124496aecc1c'
        'SKIP')
validpgpkeys=('AE1A7BA4EFFF9A9987E1474C4BACCAB36E7FE9A1') # The VirtualGL Project (Signing key for official binaries) <information@VirtualGL.org>

prepare() {
  cd VirtualGL-$pkgver

  # FS#48403
  export LDFLAGS="${LDFLAGS/--as-needed,}"
}

build() {
  cd "VirtualGL-$pkgver"

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=/usr/lib32 \
        -DCMAKE_INSTALL_BINDIR=/usr/bin \
        -DCMAKE_BUILD_TYPE='None' \
        -DTJPEG_INCLUDE_DIR=/usr/include \
        -DTJPEG_LIBRARY=/usr/lib32/libturbojpeg.so \
        -DX11_X11_LIB=/usr/lib32/libX11.so \
        -DX11_Xext_LIB=/usr/lib32/libXext.so \
        -DOPENGL_gl_LIBRARY=/usr/lib32/libGL.so \
        -Wno-dev \
        -B build \
        -S .
  make VERBOSE=1 -C build
}

package() {
  cd "VirtualGL-$pkgver"
  make install DESTDIR="$pkgdir" -C build

  cd "$pkgdir/usr"
  mv bin/glxspheres glxspheres32
  rm -rf bin
  mkdir -p bin
  mv glxspheres32 bin/

  rm -rf "$pkgdir/usr/share"
  rm -rf "$pkgdir/usr/include"
}
