# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>

pkgname=liquidctl
pkgver=1.7.1
pkgrel=1
arch=('any')
url='https://github.com/liquidctl/liquidctl'
license=('GPL3')
pkgdesc='Cross-platform CLI and Python drivers for AIO liquid coolers and other devices'
depends=('python' 'python-docopt' 'python-pyusb' 'python-hidapi' 'python-colorlog' 'i2c-tools')
makedepends=('git' 'python-setuptools')
checkdepends=('python-pytest')
source=("git+$url.git?signed#tag=v$pkgver")
validpgpkeys=('23F335ED4E829797734B22F65841AF7406AF7AD0') # Jonas Tadeu Silva Malaco Filho <jonas@jonasmalaco.com>
sha512sums=('SKIP')

build() {
  cd $pkgname

  export DIST_NAME='Arch Linux'
  export DIST_PACKAGE="$pkgver-$pkgrel"

  python setup.py build

  gzip liquidctl.8
}

check() {
  cd $pkgname

  mkdir runtime
  XDG_RUNTIME_DIR=runtime python -m pytest
}

package() {
  cd $pkgname

  python setup.py install --root "$pkgdir" --skip-build -O1

  install -Dm 644 extra/linux/71-liquidctl.rules "$pkgdir"/usr/lib/udev/rules.d/71-liquidctl.rules

  # Install documentation
  install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  cp -r -a --no-preserve=ownership docs/* "$pkgdir"/usr/share/doc/$pkgname
  install -Dm 644 liquidctl.8.gz "$pkgdir"/usr/share/man/man8/liquidctl.8.gz
}

