# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: kirek <rbuldo@gmail.com>
# Contributor: Cédric Bellegarde <gnumdk@gmail.com>

pkgname=lollypop
pkgver=1.4.23
pkgrel=1
pkgdesc='Music player for GNOME'
arch=(any)
url=https://gitlab.gnome.org/World/lollypop
license=(GPL)
depends=(
  appstream-glib
  gst-plugins-base-libs
  gst-python
  gtk3
  libhandy
  python-beautifulsoup4
  python-cairo
  python-gobject
  python-pillow
  totem-plparser
)
makedepends=(
  git
  gobject-introspection
  intltool
  itstool
  meson
)
optdepends=(
  'easytag: Modify tags'
  'gst-libav: FFmpeg plugin for GStreamer'
  'gst-plugins-bad: "Bad" plugin libraries'
  'gst-plugins-base: "Base" plugin libraries'
  'gst-plugins-good: "Good" plugin libraries'
  'gst-plugins-ugly: "Ugly" plugin libraries'
  'kid3-qt: Store covers in tags'
  'libsecret: Last.FM support'
  'youtube-dl: Youtube support'
)
_tag=7a6d6effab9b0f2c506aaf32801d91d55ec50239
source=(git+https://gitlab.gnome.org/World/lollypop.git#tag=${_tag})
sha256sums=(SKIP)

pkgver() {
  cd lollypop

  git describe --tags
}

build() {
  arch-meson lollypop build \
    --libexecdir=lib/lollypop
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" ninja -C build install
}

# vim: ts=2 sw=2 et:
