# Maintainer : Christian Rebischke <Chris.Rebischke@archlinux.org>
# Contributor: Jan Hicken <firstname [dot] lastname [at] posteo [dot] de>

pkgname=networkmanager-strongswan
_pkgname=NetworkManager-strongswan
pkgver=1.5.2
pkgrel=2
pkgdesc="Strongswan NetworkManager plugin"
arch=('x86_64')
url="https://wiki.strongswan.org/projects/strongswan/wiki/NetworkManager"
license=('GPL')
depends=('libnm' 'libsecret' 'strongswan>=5.5.1')
makedepends=('libnma' 'intltool')
optdepends=('libnma: GUI support')
source=("https://download.strongswan.org/NetworkManager/$_pkgname-$pkgver.tar.bz2"{,.sig})
sha512sums=('c79f011470778ae05f80b71330acfd7df75363fd089624007e9bdd82b75513a23eaaa3ef10141f780df075eb501ee675e4c293710e0a4c5fd9d4f4b0565bae59'
            'SKIP')
validpgpkeys=('12538F8F689B5F1F15F07BE1765FE26C6B467584') # Tobias Brunner

build() {
  cd "$_pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --disable-static --disable-more-warnings \
    --without-libnm-glib --with-charon=/usr/lib/strongswan/charon-nm
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd "$_pkgname-$pkgver"
  make check
}

package() {
  cd "$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
