# Maintainer: David Runge <dvzrv@archlinux.org>

_name=Gem
pkgname=pd-gem
pkgver=0.94
pkgrel=6
pkgdesc="Graphics Environment for Multimedia"
arch=('x86_64')
url="https://github.com/umlaeute/Gem"
license=('GPL2')
groups=('pd-externals')
# TODO: potentially add gmerlin, libmpeg3 and glewmx (if that's still a thing)
depends=('assimp' 'ftgl' 'glew' 'libdv' 'libiec61883' 'libquicktime' 'pd'
'sdl2' 'ttf-dejavu' 'zlib')
makedepends=('imagemagick' 'libvncserver' 'vlc')
optdepends=('vlc: video capture support'
            'libvncserver: video capture support'
            'imagemagick: image processing support')
source=("$pkgname-$pkgver.tar.gz::https://github.com/umlaeute/${_name}/archive/v${pkgver}.tar.gz")
sha512sums=('356e4f2a27131f927cd5d20ba9010088cc22930f313f61f54dd107db041b6cb2042ab5d530bae069e3ccdccd0a8fed1152631c6f187f4f4602f37d763356d316')
b2sums=('1ca45c5a71e094aef04778538e6d0c83f4b13f233e6038507d5510ca904476f19ed1e70c011796e66e3688f8a8b40b13f823678b6b1baba877ac0b67eb9c6698')

prepare() {
  mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
  cd "$pkgname-$pkgver"
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr \
              --with-default-font=/usr/share/fonts/TTF/DejaVuSans.ttf
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
}
