# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: jason ryan <jasonwryan@gmail.com>
# Contributor: Christian Rebischke <chris.rebischke@archlinux.org>

pkgbase=profanity
pkgname=('profanity' 'profanity-gtk')
pkgver=0.11.0
pkgrel=1
epoch=1
pkgdesc='Console based XMPP client'
url='http://www.profanity.im'
arch=('x86_64')
license=('GPL3')
makedepends=(
  'curl' 'ncurses' 'expat' 'glib2' 'libotr' 'libmesode' 'libnotify' 'gpgme'
  'python' 'gtk2' 'autoconf-archive' 'libsignal-protocol-c' 'libgcrypt'
  'libx11' 'libxss' 'libxcrypt' 'glibc' 'freetype2' 'readline' 'libassuan'
  'harfbuzz' 'pango' 'gdk-pixbuf2' 'atk' 'cairo' 'libgpg-error')
checkdepends=('cmocka')
source=(https://github.com/profanity-im/profanity/archive/${pkgver}/${pkgbase}-${pkgver}.tar.gz)
sha256sums=('3947be0fddb0545ad2addc0ac90053ef93327f5b1177ef9aed154ab59630512e')
sha512sums=('b1c6d3f963534539a9ceb037f87e42239c04c267ec3db7b1b6342e8d6a86cce6495a63dafaca42a9c5dfa53e03b0dfbc621f0764731ac11c0ce82313f708d234')
b2sums=('b784597cab3c98b7936ec1af937f6d5afbb15e2045e3b1b1fa6146e7a98aa41b058f13f7f8907b56f93b93f621925750255ee86da1635ed7ff0e59f22403f9f1')

prepare() {
  cd ${pkgname}-${pkgver}
  mkdir -p m4
  autoreconf -fiv
  cp -a "${srcdir}"/${pkgname}-${pkgver}{,-gtk}
}

build() {
  echo "Building non-gtk variant..."
  (cd ${pkgname}-${pkgver}
    ./configure \
      --prefix=/usr \
      --disable-icons-and-clipboard \
      --without-xscreensaver \
      --enable-notifications \
      --enable-python-plugins \
      --enable-c-plugins \
      --enable-plugins \
      --enable-otr \
      --enable-omemo \
      --enable-pgp
    make
  )
  echo "Building gtk variant..."
  (cd ${pkgname}-${pkgver}-gtk
    ./configure \
      --prefix=/usr \
      --enable-icons-and-clipboard \
      --with-xscreensaver \
      --enable-notifications \
      --enable-python-plugins \
      --enable-c-plugins \
      --enable-plugins \
      --enable-otr \
      --enable-omemo \
      --enable-pgp
    make
  )
}

package_profanity() {
  depends=(
    'curl' 'libcurl.so' 'ncurses' 'libncursesw.so' 'expat' 'glib2' 'libotr'
    'libmesode' 'libmesode.so' 'libnotify' 'libnotify.so' 'libxcrypt' 'libcrypt.so'
    'gpgme' 'libgpgme.so' 'python' 'libgcrypt' 'libsignal-protocol-c'
    'glibc' 'readline' 'libreadline.so' 'libassuan' 'libgpg-error'
  )
  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install
}

package_profanity-gtk() {
  pkgdesc+=' (gtk support)'
  depends=(
    'curl' 'libcurl.so' 'ncurses' 'libncursesw.so' 'expat' 'glib2' 'libotr'
    'libmesode' 'libmesode.so' 'libnotify' 'libnotify.so' 'libxcrypt' 'libcrypt.so'
    'gpgme' 'libgpgme.so' 'python' 'libgcrypt' 'libsignal-protocol-c'
    'glibc' 'readline' 'libreadline.so' 'libassuan' 'libgpg-error'

    'gtk2' 'libxss' 'libx11' 'pango' 'libpango-1.0.so' 'libpangoft2-1.0.so'
    'freetype2' 'libfreetype.so' 'harfbuzz' 'libharfbuzz.so' 'gdk-pixbuf2'
    'atk' 'libatk-1.0.so' 'cairo'
  )
  provides=('profanity')
  conflicts=('profanity')
  cd ${pkgbase}-${pkgver}-gtk
  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et:
