# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Ian Denhardt <ian@zenhack.net>

_pkgname=urwidtrees
pkgname=python-urwidtrees
pkgver=1.0.3
pkgrel=5
pkgdesc="Tree widgets for urwid."
arch=(any)
url="https://github.com/pazz/$_pkgname"
license=(GPL3)
makedepends=(python-sphinx)
depends=(python 'python-urwid>=1.1.0')
source=("$_pkgname-$pkgver.tar.gz::https://github.com/pazz/$_pkgname/archive/$pkgver.tar.gz"
        "https://github.com/pazz/urwidtrees/commit/ed39dbc4fc67b0e0249bf108116a88cd18543aa9.patch")
md5sums=('44068550c3f538d64b667dc52eeca6cb'
         '7489b033cddaf0e655896b1a2fb2ea61')

prepare() {
	cd "$srcdir/$_pkgname-$pkgver"

    # drop unneeded mock dependency: https://github.com/pazz/urwidtrees/issues/48
    patch -p1 -i ../ed39dbc4fc67b0e0249bf108116a88cd18543aa9.patch
}

build() {
	cd "$srcdir/$_pkgname-$pkgver"
	python setup.py build
	make SPHINXBUILD=sphinx-build -C docs man html
}

package_python-urwidtrees() {
	cd "$srcdir/$_pkgname-$pkgver"

	python setup.py install --optimize=1 --root="$pkgdir"

	install -dm755 "$pkgdir/usr/share/doc/$pkgname"
	cp -a docs/build/html/* "$pkgdir/usr/share/doc/$pkgname"
}
