# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: Jkkyll Wu <adaptee at gmail [dot] com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>

pkgbase=qbittorrent
pkgname=(qbittorrent qbittorrent-nox)
pkgver=4.3.8
pkgrel=1
arch=('x86_64')
url="https://www.qbittorrent.org"
license=('custom' 'GPL')
depends=('libtorrent-rasterbar' 'qt5-base')
makedepends=('boost' 'qt5-tools' 'qt5-svg')
optdepends=('python: needed for torrent search tab')
source=("https://downloads.sourceforge.net/sourceforge/qbittorrent/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha512sums=('1983bb97c8ba0f7cd36dcbb7af7428af3d69b3804fb93b9eee8da65f301e49a4f074a849331dbb69f70b2d27d8730b34833ca185cb3dda5c379010d146d6215f'
            'SKIP')
b2sums=('effa8963ca350b7b7a13adcfb711f33553db6f9bbe8d0c2155aa004f2101d9903ffbfd328ac91d78387de96a1e9e8acd5f642d1e4150e14d023ab8da98ff9381'
        'SKIP')
validpgpkeys=('D8F3DA77AAC6741053599C136E4A2D025B7CC9A2') # sledgehammer999 <sledgehammer999@qbittorrent.org>

build() {
  cd ${pkgbase}-${pkgver}

  # tell qmake not to break makepkg's debug/!strip options
  export QBT_ADD_CONFIG='nostrip'

  mkdir -p ${pkgbase}
  pushd ${pkgbase}
  ../configure --prefix=/usr
  make
  popd

  # Build nox variant
  mkdir -p "${pkgbase}-nox"
  pushd "${pkgbase}-nox"
  ../configure --prefix=/usr --disable-gui --enable-systemd
  make
}

package_qbittorrent() {
  pkgdesc="An advanced BitTorrent client programmed in C++, based on Qt toolkit and libtorrent-rasterbar."
  depends+=('qt5-svg' 'hicolor-icon-theme')

  cd ${pkgbase}-${pkgver}/${pkgbase}

  make INSTALL_ROOT="${pkgdir}" install
  install -Dm644 "${srcdir}"/${pkgbase}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
}

package_qbittorrent-nox() {
  pkgdesc="An advanced BitTorrent client programmed in C++, based on Qt toolkit and libtorrent-rasterbar, w/o gui"

  cd ${pkgbase}-${pkgver}/${pkgbase}-nox

  make INSTALL_ROOT="${pkgdir}" install
  install -Dm644 "${srcdir}"/${pkgbase}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
}
