# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Bruno Pagani <archange@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=quodlibet
pkgver=4.4.0
pkgrel=2
pkgdesc="Music player and music library manager"
arch=(any)
url="https://quodlibet.readthedocs.io/"
license=(GPL2)
depends=(dbus-python gtk3 python-cairo python-feedparser python-gobject python-mutagen)
makedepends=(python-sphinx_rtd_theme)
# python-raven python-senf are currently vendored
checkdepends=(gst-plugins-base gst-plugins-good python-pytest python-xvfbwrapper)
optdepends=('gst-libav: Extra media codecs for the GStreamer backend'
            'gst-plugins-bad: Extra media codecs for the GStreamer backend; Audio Pitch / Speed, Crossfeed, Submit Acoustic Fingerprints plugins'
            'gst-plugins-base: Default audio backend'
            'gst-plugins-good: Extra media codecs, PulseAudio support for the GStreamer backend; Audio Compressor, Karaoke, Replay Gain plugins'
            'gst-plugins-ugly: Extra media codecs for the GStreamer backend'
            'gtksourceview3: Undo and redo support in multiline text fields'
            'kakasi: Kana/Kanji Simple Inverter plugin'
            'libappindicator-gtk3: Appindicator support in the Tray Icon plugin'
            'libkeybinder3: Multimedia key support under non Gnome setups'
            'libmodplug: MOD support'
            'python-musicbrainzngs: MusicBrainz Lookup, MusicBrainz Sync plugins'
            'python-paho-mqtt: MQTT Publisher plugin'
            'python-pyinotify: Automatic Library Update plugin'
            'rygel: UPnP AV Media Server plugin'
            'webkit2gtk: Web Lyrics plugin'
            'xine-lib: Alternative audio backend')
source=("https://github.com/${pkgname}/${pkgname}/releases/download/release-${pkgver}/${pkgname}-${pkgver}.tar.gz"{,.sig})
sha256sums=(a03318d2767e4959551763d0a87fad977387af712608fe572714176a24bbf367 SKIP)
validpgpkeys=(0EBF782C5D53F7E5FB02A66746BD761F7A49B0EC) # Christoph Reiter <reiter.christoph@gmail.com>

prepare() {
  cd ${pkgname}-${pkgver}
  # Fix zsh completions dir
  sed -e 's|vendor-completions|site-functions|' -i gdist/zsh_completions.py
}

build() {
  cd ${pkgname}-${pkgver}
  python setup.py build
}

check() {
  cd ${pkgname}-${pkgver}
  export PYTHONPATH="build:${PYTHONPATH}"
  # not running useless linter checks
  pytest -v -k 'not TFlake8'
}

package() {
  cd ${pkgname}-${pkgver}
  python setup.py install --root="${pkgdir}" --skip-build --optimize=1
  install -Dm644 {README,NEWS}.rst -t "${pkgdir}"/usr/share/doc/${pkgname}
}
