# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>

pkgname=r8168-lts
pkgver=8.049.02
pkgrel=20
pkgdesc="A kernel module for Realtek 8168 network cards for linux-lts"
url="http://www.realtek.com.tw"
license=("GPL")
arch=('x86_64')
makedepends=('linux-lts-headers')
source=(https://github.com/mtorromeo/r8168/archive/$pkgver/r8168-$pkgver.tar.gz
        https://github.com/mtorromeo/r8168/releases/download/$pkgver/r8168-$pkgver.tar.gz.asc)
sha256sums=('2b12d932e976f8f74b8d9545744c04beb4676dd7bc1d032dde51347ed1d8be24'
            'SKIP')
validpgpkeys=('0CADAACF70F64C654E131B3111675C743429DDEF')

build() {
	cd "r8168-$pkgver"
	# avoid using the Makefile directly -- it doesn't understand
	# any kernel but the current.
	make -C /usr/src/linux-lts M="$PWD/src" \
		ENABLE_USE_FIRMWARE_FILE=y \
		CONFIG_R8168_NAPI=y \
		CONFIG_R8168_VLAN=y \
		CONFIG_ASPM=y \
		ENABLE_S5WOL=y \
		ENABLE_EEE=y \
		modules
}

package() {
	depends=('glibc' 'linux-lts')

	local extradir=/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules
	cd "r8168-$pkgver"
	install -Dt "$pkgdir$extradir" -m644 src/*.ko
	find "$pkgdir" -name '*.ko' -exec xz {} +

	echo "blacklist r8169" | \
		install -Dm644 /dev/stdin "$pkgdir/usr/lib/modprobe.d/$pkgname.conf"
}

# vim:set sw=0 noet:
