# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Robert Emil Berge <robert@rebi.no>

pkgname=rosegarden
pkgver=21.06.1
pkgrel=1
pkgdesc="MIDI/audio sequencer and notation editor"
arch=('x86_64')
url="https://www.rosegardenmusic.com/"
license=('GPL2')
groups=('pro-audio')
depends=('gcc-libs' 'glibc' 'lirc' 'hicolor-icon-theme' 'qt5-base' 'zlib')
makedepends=('alsa-lib' 'cmake' 'dssi' 'fftw' 'jack' 'ladspa' 'liblrdf' 'liblo'
'libsamplerate' 'libsndfile' 'qt5-tools')
checkdepends=('xorg-server-xvfb')
optdepends=('cups: Printing support'
            'evince: Print preview support'
            'lilypond: Notation display support'
            'mupdf: Print preview support'
            'okular: Print preview support'
            'timidity++: Softsynth support'
            'flac: FLAC support'
            'wavpack: Lossless audio codec support')
provides=('dssi-host' 'ladspa-host')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('a0214d95c26e01c5c0ce671bf23f4ebe7f63e54cecf6471226768aae5b4ce8dcf9f03a1970c26317d734a16a0d741d83ce684a53f115db656538522b373ef7a6')
b2sums=('c18e1b6d14c2caac1ac7a2ddba2d40fb5a19d8a6468b81c696267ac984875db58943ec0fd46afe4b5d511afa1f5cb1ada93205b6088effcaf75adf234beaa516')

build() {
  cd "${pkgname}-${pkgver}"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE='None' \
        -Wno-dev \
        -B build \
        -S .
  make VERBOSE=1 -C build
}

check() {
  cd "${pkgname}-${pkgver}"
  mkdir -p test-tmp
  chmod 700 test-tmp
  export XDG_RUNTIME_DIR="${PWD}/test-tmp"
  xvfb-run make VERBOSE=1 test -C build || echo "TestNotationViewSelection still fails: https://sourceforge.net/p/rosegarden/bugs/1585/"
}

package() {
  depends+=('libasound.so' 'libfftw3f.so' 'libjack.so' 'liblrdf.so' 'liblo.so'
  'libsamplerate.so' 'libsndfile.so')
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install -C build
  install -vDm 644 {AUTHORS,CHANGELOG,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim:set ts=2 sw=2 et:
