# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ner0 <darkelfdarkelf666@yahoo.co.uk>
# Contributor: dserban <dserban01@yahoo.com>

pkgname=switchboard
pkgver=6.0.0
pkgrel=1
pkgdesc='The Pantheon Control Center'
arch=(x86_64)
url=https://github.com/elementary/switchboard
license=(GPL3)
groups=(pantheon)
depends=(
  clutter-gtk
  gdk-pixbuf2
  glib2
  gtk3
  libgee
  libgranite.so
  libhandy-1.so
  wayland
)
makedepends=(
  git
  meson
  intltool
  vala
)
optdepends=(
  'switchboard-plug-about: About plug'
  'switchboard-plug-applications: Applications plug'
  'switchboard-plug-datetime: Date & Time plug'
  'switchboard-plug-desktop: Desktop plug'
  'switchboard-plug-display: Display plug'
  'switchboard-plug-elementary-tweaks: Elementary Tweaks plug'
  'switchboard-plug-keyboard: Keyboard plug'
  'switchboard-plug-locale: Locale plug'
  'switchboard-plug-network: Network plug'
  'switchboard-plug-notifications: Notifications plug'
  'switchboard-plug-power: Power plug'
  'switchboard-plug-security-privacy: Security & Privacy plug'
)
provides=(libswitchboard-2.0.so)
_tag=f4a24fdcff6d0bb96ead0b967d681d35e999f84c
source=(git+https://github.com/elementary/switchboard.git#tag=${_tag})
sha256sums=(SKIP)

pkgver() {
  cd switchboard

  git describe --tags
}

build() {
  arch-meson switchboard build \
    -D libunity=false
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et:
