# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Nick Østergaard <oe.nick@gmail.com>
# Contributor: Jonny Gerold <jonny@fsk141.com>

pkgname=viking
pkgver=1.9
pkgrel=2
pkgdesc="GTK application to manage GPS data"
arch=('x86_64')
url="https://sourceforge.net/projects/viking/"
license=('GPL2')
depends=('curl' 'file' 'gpsd' 'gtk3' 'libgexiv2' 'mapnik' 'geoclue' 'liboauth' 'libzip')
makedepends=('boost' 'docbook-xsl' 'intltool' 'itstool')
optdepends=('gpsbabel: import and export GPS tracks from various formats')
changelog=$pkgname.changelog
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2
        https://raw.githubusercontent.com/viking-gps/$pkgname/$pkgname-$pkgver/org.viking.Viking.appdata.xml)
sha256sums=('fe4acf3d24121d6f3097d17ea704b42c0336a8f693151886b8b26e308dbfcb3b'
            '2a3d60bfed29db9ebc973f02a769c347cb04dafd474fb499448f27de0bbede0f')

prepare() {
  sed -i 's/org.viking.Viking.desktop/viking.desktop/' org.viking.Viking.appdata.xml
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver

  export CXXFLAGS="$CXXFLAGS -I/usr/include/mapnik"
  ./configure --prefix=/usr
  make
}

package(){
  cd "${srcdir}"/$pkgname-$pkgver

  make DESTDIR="${pkgdir}" install
  install -Dm644 ../org.viking.Viking.appdata.xml "${pkgdir}"/usr/share/metainfo/viking.appdata.xml
}
