# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Elrondo46 TuxnVape <elrond94@hotmail.com>
# Contributor: Ivan Fonseca <ivanfon@riseup.net>
# Contributor: Alfredo Ramos <alfredo dot ramos at yandex dot com>
# Contributor: Giacomo <giacomogiorgianni at gmail dot com>

pkgname=vokoscreen
_pkgname=vokoscreenNG
pkgver=3.0.9
pkgrel=1
pkgdesc='Easy to use screencast creator'
arch=('x86_64')
url='https://linuxecke.volkoh.de/vokoscreen/vokoscreen.html'
license=('GPL2')
depends=('gst-plugins-good' 'qt5-multimedia' 'qt5-x11extras')
optdepends=('gst-plugins-bad: record audio into AAC format'
            'gst-plugins-ugly: record screen into H.264 format')
makedepends=('qt5-tools')
source=("https://github.com/vkohaupt/$_pkgname/archive/$pkgver/$_pkgname-$pkgver.tar.gz"
        '0001-Add-better-integration-for-Linux.patch')
sha256sums=('e03ebce15d624eb64a37a7448d5e583eb56d38f7b569be24cedaa6632d5c65a6'
            '1d9c78a9c43f64a6c47ac916da5bdea7e686f1aae2264db9e7a7b2504b76efb0')

prepare() {
  cd $_pkgname-$pkgver
  patch -Np1 -i ../0001-Add-better-integration-for-Linux.patch
}

build() {
  cd $_pkgname-$pkgver
  qmake-qt5 PREFIX=/usr src/vokoscreenNG.pro
  make
}

package() {
  cd $_pkgname-$pkgver
  make INSTALL_ROOT="$pkgdir" install
}
