# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Gerardo Exequiel Pozzi <djgera@archlinux.org>

pkgname=archiso
pkgver=58
pkgrel=1
pkgdesc='Tools for creating Arch Linux live and install iso images'
arch=('any')
license=('GPL3')
url="https://gitlab.archlinux.org/archlinux/archiso"
depends=('arch-install-scripts' 'bash' 'dosfstools' 'e2fsprogs' 'libarchive'
'libisoburn' 'mtools' 'squashfs-tools')
makedepends=('git')
checkdepends=('shellcheck')
optdepends=(
  'edk2-ovmf: for emulating UEFI with run_archiso'
  'erofs-utils: for experimental EROFS support in mkarchiso'
  'openssl: for codesigning support when building netboot artifacts'
  'qemu: for run_archiso'
)
source=("git+https://gitlab.archlinux.org/archlinux/archiso.git#tag=v${pkgver}?signed")
sha256sums=('SKIP')
validpgpkeys=('C7E7849466FE2358343588377258734B41C31549') # David Runge <dvzrv@archlinux.org>

check() {
  cd "${pkgbase}"
  make -k check
}

package() {
  cd "${pkgbase}"
  make DESTDIR="${pkgdir}" PREFIX='/usr' install
}
