# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>

pkgname=gnome-books
pkgver=40.0
pkgrel=1
pkgdesc="Access and organize your e-books on GNOME"
url="https://wiki.gnome.org/Apps/Books"
arch=(x86_64)
license=(GPL)
depends=(evince gjs gtk3 gnome-desktop tracker3-miners webkit2gtk libgepub
         gnome-epub-thumbnailer)
makedepends=(gobject-introspection git meson yelp-tools)
groups=(gnome)
_commit=e5a6646a5586f36e0ee3167a77237b4c7eaff8e0  # tags/40.0^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-books.git#commit=$_commit"
        "git+https://gitlab.gnome.org/GNOME/libgd.git")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git submodule set-url subprojects/libgd "$srcdir/libgd"
  git submodule update
}
  

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}

# vim:set ts=2 sw=2 et:
