# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>

pkgname=gnome-themes-extra
pkgver=3.28
pkgrel=2
pkgdesc="Extra Themes for GNOME Applications"
url="https://gitlab.gnome.org/GNOME/gnome-themes-extra"
arch=(x86_64)
license=(LGPL2.1)
depends=(cantarell-fonts)
makedepends=(intltool gtk2 gtk3 git)
optdepends=('gtk-engines: HighContrast GTK2 theme')
provides=("gnome-themes-standard=$pkgver")
conflicts=(gnome-themes-standard)
replaces=('gnome-themes-standard<3.27.92')
groups=(gnome)
_commit=9f581269243dd7e76b3eb8cec9cf4128ab17da9e  # tags/3.28^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-themes-extra.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  mkdir m4
  intltoolize
  autoreconf -fvi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
