# Maintainer: AndyRTR <andyrtr@archlinux.org>

pkgname=libcmis
pkgver=0.5.2
pkgrel=8
pkgdesc="a C/C++ client library for the CMIS protocol"
arch=('x86_64')
url="https://github.com/tdf/libcmis"
license=('GPL2' 'LGPL2.1' 'MPL')
depends=('boost-libs' 'curl' 'libxml2')
makedepends=('docbook2x' 'cppunit' 'boost')
source=("https://github.com/tdf/libcmis/releases/download/v${pkgver}/$pkgname-$pkgver.tar.gz"
        'libcmis-0.5.2-icu-64.2.patch')
sha256sums=('ed6f681a48abbf3c2324564b17a180d21fa9503230e8708825e1ad80daee4f81'
            '51b67a5b7245e5192739362c5034ed7d9a664799f38ff9ccd1832297f93cc03d')

prepare() {
  cd "$pkgname-$pkgver"

  # https://github.com/tdf/libcmis/issues/35
  patch -Np1 -i ../libcmis-0.5.2-icu-64.2.patch
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr DOCBOOK2MAN='db2x_docbook2man' --disable-werror
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd "$pkgname-$pkgver"
  # fails a google drive check - fix will be included in the next release
  make check || /bin/true
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
}
