# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=liferea
pkgver=1.13.6
pkgrel=1
pkgdesc="A desktop news aggregator for online news feeds and weblogs"
arch=('x86_64')
url="https://lzone.de/liferea"
license=('GPL')
depends=('webkit2gtk' 'libpeas' 'python-gobject')
makedepends=('intltool' 'gobject-introspection')
optdepends=('libsecret: for keyring plugin support'
            'python-cairo: for the tray icon plugin'
	    'gst-plugins-base: for media player plugin support'
	    'gst-plugins-good: for media player plugin support'
	    'gst-plugins-bad: for media player plugin support')
options=('!emptydirs')
source=(https://github.com/lwindolf/liferea/releases/download/v$pkgver/$pkgname-${pkgver}.tar.bz2)
sha256sums=('c192b891c944061f9f5261f67cdf88c22cae05e7ca04cf6218d8688c4a73d298')

build() {
  cd $pkgname-${pkgver}
  
  # https://github.com/lwindolf/liferea/issues/767
  export WEBKIT_DISABLE_COMPOSITING_MODE=1
  
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-schemas-compile
  make
}

package() {
  cd $pkgname-${pkgver}
  make DESTDIR="${pkgdir}" install
}
