# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=qt6-multimedia
_qtver=6.2.0-rc2
pkgver=${_qtver/-/}
pkgrel=1
arch=(x86_64)
url='https://www.qt.io'
license=(GPL3 LGPL3 FDL custom)
pkgdesc='Classes for audio, video, radio and camera functionality'
depends=(qt6-base gst-plugins-base)
makedepends=(cmake ninja qt6-declarative qt6-shadertools)
optdepends=('qt6-declarative: QML bindings'
            'gst-plugins-good: camera support, additional plugins'
            'gst-plugins-bad: camera support, additional plugins'
            'gst-plugins-ugly: additional plugins'
            'gst-libav: ffmpeg plugin')
groups=(qt6)
_pkgfn="${pkgname/6-/}-everywhere-src-$_qtver"
source=(https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
sha256sums=('a8cbf19a11b141567cd3f13b1f4ec3e19c6319316dceec8fca33c267120c51e5')

build() {
  cmake -B build -S $_pkgfn -G Ninja
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
}
