# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=vino
pkgver=3.22.0+74+g7a95e10
pkgrel=1
pkgdesc="A VNC server for the GNOME desktop"
url="https://wiki.gnome.org/Projects/Vino"
arch=(x86_64)
license=(GPL)
depends=(libnotify libxtst libsm telepathy-glib gtk3 libsecret avahi gnutls)
makedepends=(intltool networkmanager gnome-common git)
groups=(gnome)
_commit=7a95e105ec0a68dc0057b12ab4d15d628511a559  # master
source=("git+https://gitlab.gnome.org/GNOME/vino.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/vino \
      --localstatedir=/var \
      --disable-http-server --with-secret

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}
